AS3 Application Preloading – translated

Juten Tach,

this is an article, i wrote last year. It was in german. Since i switched the language to english, i thought i translate this article to english as well. Here it goes:

My colleague Lars described in his article, how to use the [Frame] Tag together with a Factory class in order to preload your Main application by spreading your classes on different frames. Since it was a bit of work to do to accomplish that i felt i give it a try and seach for another solution that might be easier and i found a compiler-option based solution.

As an example, the following two classes are given:

The Main class:

package {
   import flash.display.DisplayObject;
   import flash.display.MovieClip;
   import flash.events.Event;
   import flash.utils.getDefinitionByName;

   public class Test extends MovieClip {
      public function Test() {
         stop();
         addEventListener(
            Event.ENTER_FRAME,
            onEnterFrame
         );
      }

      public function onEnterFrame(event:Event):void {
         if(framesLoaded == totalFrames) {
            removeEventListener(
               Event.ENTER_FRAME,
               onEnterFrame
            );
            nextFrame();
            init();
         }else {
            // Show loading stuff here.
         }
      }

      private function init():void {
         var mainClass:Class = Class(
            getDefinitionByName("Demo")
         );
         if(mainClass) {
            var app:Object = new mainClass();
            addChild(app as DisplayObject);
         }
      }
   }
}

And secondly, the actual application class, which should come to play in frame two:

package {
   import flash.display.Bitmap;
   import flash.display.Sprite;

   public class Demo extends Sprite {
      [Embed(source="somepicture.jpg")]
      private var picture:Class;
      public function Demo() {
         init();
      }

      private function init():void {
         trace("Hello Demo");
         var asset:Bitmap = new picture();
         addChild(asset);
      }
   }
}

But the most important part comes now, the following compiler option:

-frame two Demo

That simply puts the class Demo in a second frame called “two”. You can use the “-frame” compiler option as many times as you want for adding even more frames. The big advantage here is, that you don’t get these nasty flex classes in your application, that you don’t want. Everything’s nice and slender.

Unfortunately though, the Embed Tag in my class Demo still causes the mxmlc to compile a bunch of flex classes and interfaces into my app. Seems, that you cannot really do something about that, which is sad, because i don’t see, why i need a flex bitmap object, when a normal Bitmap Object would have been good enough.